Эта функция наконец-то поддерживается в C # 7.3!
Следующий фрагмент (из ) демонстрирует, как:
public static Dictionary<int, string> EnumNamedValues<T>() where T : System.Enum
{
var result = new Dictionary<int, string>();
var values = Enum.GetValues(typeof(T));
foreach (int item in values)
result.Add(item, Enum.GetName(typeof(T), item));
return result;
}
Обязательно установите для своей языковой версии в проекте C # версию 7.3.
Оригинальный ответ ниже:
Я опаздываю на игру, но я воспринял это как вызов, чтобы увидеть, как это можно сделать. Это невозможно в C # (или VB.NET, но прокрутите вниз для F #), но возможно в MSIL. Я написал эту маленькую .... вещь
// license: http://www.apache.org/licenses/LICENSE-2.0.html
.assembly MyThing{}
.class public abstract sealed MyThing.Thing
extends [mscorlib]System.Object
{
.method public static !!T GetEnumFromString<valuetype .ctor ([mscorlib]System.Enum) T>(string strValue,
!!T defaultValue) cil managed
{
.maxstack 2
.locals init ([0] !!T temp,
[1] !!T return_value,
[2] class [mscorlib]System.Collections.IEnumerator enumerator,
[3] class [mscorlib]System.IDisposable disposer)
// if(string.IsNullOrEmpty(strValue)) return defaultValue;
ldarg strValue
call bool [mscorlib]System.String::IsNullOrEmpty(string)
brfalse.s HASVALUE
br RETURNDEF // return default it empty
// foreach (T item in Enum.GetValues(typeof(T)))
HASVALUE:
// Enum.GetValues.GetEnumerator()
ldtoken !!T
call class [mscorlib]System.Type [mscorlib]System.Type::GetTypeFromHandle(valuetype [mscorlib]System.RuntimeTypeHandle)
call class [mscorlib]System.Array [mscorlib]System.Enum::GetValues(class [mscorlib]System.Type)
callvirt instance class [mscorlib]System.Collections.IEnumerator [mscorlib]System.Array::GetEnumerator()
stloc enumerator
.try
{
CONDITION:
ldloc enumerator
callvirt instance bool [mscorlib]System.Collections.IEnumerator::MoveNext()
brfalse.s LEAVE
STATEMENTS:
// T item = (T)Enumerator.Current
ldloc enumerator
callvirt instance object [mscorlib]System.Collections.IEnumerator::get_Current()
unbox.any !!T
stloc temp
ldloca.s temp
constrained. !!T
// if (item.ToString().ToLower().Equals(value.Trim().ToLower())) return item;
callvirt instance string [mscorlib]System.Object::ToString()
callvirt instance string [mscorlib]System.String::ToLower()
ldarg strValue
callvirt instance string [mscorlib]System.String::Trim()
callvirt instance string [mscorlib]System.String::ToLower()
callvirt instance bool [mscorlib]System.String::Equals(string)
brfalse.s CONDITION
ldloc temp
stloc return_value
leave.s RETURNVAL
LEAVE:
leave.s RETURNDEF
}
finally
{
// ArrayList's Enumerator may or may not inherit from IDisposable
ldloc enumerator
isinst [mscorlib]System.IDisposable
stloc.s disposer
ldloc.s disposer
ldnull
ceq
brtrue.s LEAVEFINALLY
ldloc.s disposer
callvirt instance void [mscorlib]System.IDisposable::Dispose()
LEAVEFINALLY:
endfinally
}
RETURNDEF:
ldarg defaultValue
stloc return_value
RETURNVAL:
ldloc return_value
ret
}
}
При этом создается функция, которая выглядела бы так, если бы она была действительной C #:
T GetEnumFromString<T>(string valueString, T defaultValue) where T : Enum
Затем со следующим кодом C #:
using MyThing;
// stuff...
private enum MyEnum { Yes, No, Okay }
static void Main(string[] args)
{
Thing.GetEnumFromString("No", MyEnum.Yes); // returns MyEnum.No
Thing.GetEnumFromString("Invalid", MyEnum.Okay); // returns MyEnum.Okay
Thing.GetEnumFromString("AnotherInvalid", 0); // compiler error, not an Enum
}
К сожалению, это означает, что эта часть вашего кода написана на MSIL вместо C #, с единственным дополнительным преимуществом, заключающимся в том, что вы можете ограничить этот метод с помощью System.Enum
. Это тоже своего рода облом, потому что компилируется в отдельную сборку. Однако это не означает, что вам нужно развернуть его таким образом.
Удалив строку .assembly MyThing{}
и вызвав ilasm следующим образом:
ilasm.exe /DLL /OUTPUT=MyThing.netmodule
вместо сборки вы получаете сетевой модуль.
К сожалению, VS2010 (и, очевидно, ранее) не поддерживает добавление ссылок на netmodule, что означает, что вам придется оставить его в двух отдельных сборках при отладке. Единственный способ добавить их как часть сборки - это запустить csc.exe самостоятельно с помощью аргумента командной строки /addmodule:{files}
. В сценарии MSBuild это не было бы слишком болезненно. Конечно, если вы смелы или глупы, вы можете запускать csc каждый раз вручную. И это, безусловно, становится более сложным, поскольку доступ к нему требуется нескольким сборкам.
Итак, это МОЖНО сделать в .Net. Стоит ли дополнительных усилий? Эм, ну, думаю, я позволю тебе решить это.
Решение F # как альтернатива
Дополнительная благодарность: оказывается, что общее ограничение на enum
возможно по крайней мере в одном другом языке .NET, помимо MSIL: F #.
type MyThing =
static member GetEnumFromString<'T when 'T :> Enum> str defaultValue: 'T =
/// protect for null (only required in interop with C#)
let str = if isNull str then String.Empty else str
Enum.GetValues(typedefof<'T>)
|> Seq.cast<_>
|> Seq.tryFind(fun v -> String.Compare(v.ToString(), str.Trim(), true) = 0)
|> function Some x -> x | None -> defaultValue
Его легче поддерживать, так как это хорошо известный язык с полной поддержкой IDE Visual Studio, но для него все равно нужен отдельный проект в вашем решении. Однако он, естественно, производит значительно другой IL (код очень отличается) и полагается на библиотеку FSharp.Core
, которая, как и любая другая внешняя библиотека, должна стать частью вашего дистрибутива.
Вот как вы можете его использовать (в основном так же, как решение MSIL) и показать, что он правильно не работает на синонимичных структурах:
// works, result is inferred to have type StringComparison
var result = MyThing.GetEnumFromString("OrdinalIgnoreCase", StringComparison.Ordinal);
// type restriction is recognized by C#, this fails at compile time
var result = MyThing.GetEnumFromString("OrdinalIgnoreCase", 42);
person
Christopher Currens
schedule
10.11.2011
foreach
-цикл?Enum.Parse
содержитignoreCase
-параметр (я думаю, поскольку .Net 2.0). - person Yahoo Serious   schedule 23.05.2013ignoreCase
-параметром и общим значениемdefault
в качестве дополнительных аргументов, а также некоторые другие улучшения. предложено другими. - person Yahoo Serious   schedule 24.05.2013Enum.ToString()
, а тип Enum отмечен атрибутом[Flags]
,defaultValue
всегда будет возвращаться из метода сvalue = (enum.type1 | enum.type2).ToString() == type1, type2
. Угловой шкаф. - person paxmemento   schedule 16.10.2015T
с ограничениемwhere T: Enum
компиляторы по-прежнему плачут, как младенец, что T должен иметь тип, не допускающий значения NULL , в результате чего во всей иерархии передаваемых дженериков необходимо также указать ограничениеstruct
. - person That Marc   schedule 26.05.2019